00001 PRINT NEWPAGE
00002 LET ENV_GUI$=ENV$("GUIMODE") !:
      IF ENV_GUI$<>"ON" THEN !:
      EXECUTE "CON GUI ON"
00005 DIM TBAR_FORM$*80,TBAR_ICONS$(3)*80,VBAR_FORM$*80,VBAR_ICONS$(2)*80,STATUS$(1)*132,BUFF$*1024,GRID_HANDLE$*80
00010 LET IO_WIN=100 !:
      LET WINX=1: LET WINL=80 !:
      LET WINY=3: LET WINH=20
00020 LET TBAR_FORM$="1,"&STR$(WINL-5)&",P 1/2,[S],B90;1,"&STR$(WINL-3)&",P 1/2,[S],B91;1,"&STR$(WINL-1)&",P 1/2,[S],B99"
00030 LET TBAR_ICONS$(1)="icons\MvUP.GIF:Isotropic" !:
      LET TBAR_ICONS$(2)="icons\MVDn.GIF:Isotropic" !:
      LET TBAR_ICONS$(3)="icons\X.GIF:Isotropic"
00040 LET VBAR_FORM$="1,1,P 1/2,[S],B112;"&STR$(WINH-1)&",1,P 1/2,[S],B113" ! &"3,"&STR$(WINL-1)&",P "&STR$(WINH-3)&"/2,[TOOLBAR]"
00050 LET VBAR_ICONS$(1)="icons\UP.GIF" !:
      LET VBAR_ICONS$(2)="icons\Down.GIF"
00100 OPEN #(IO_WIN): "SROW="&STR$(WINY)&",SCOL="&STR$(WINX)&",ROWS="&STR$(WINH)&",COLS="&STR$(WINL),DISPLAY,OUTIN 
00110 PRINT #IO_WIN: NEWPAGE
00120 OPEN #(TOOLBAR_HANDLE:=FNGETHANDLE): "SROW=1,SCOL=1,ROWS=1,COLS="&STR$(WINL)&",parent="&STR$(IO_WIN)&",picture=icons\ToolBar.Gif" ,DISPLAY,OUTIN 
00130 OPEN #(VBAR_HANDLE:=FNGETHANDLE): "SROW=2,SCOL="&STR$(WINL-1)&",ROWS="&STR$(WINH-1)&",COLS=2,parent="&STR$(IO_WIN)&",picture=icons\VBar.Gif" ,DISPLAY,OUTIN 
00200 PRINT #TOOLBAR_HANDLE,FIELDS TBAR_FORM$: MAT TBAR_ICONS$
00210 PRINT #VBAR_HANDLE,FIELDS VBAR_FORM$: MAT VBAR_ICONS$
00220 PRINT #IO_WIN,FIELDS "2,1,C,[W]": "Please Wait, Generating Status Information"
00300 EXECUTE "STATUS ALL >"&ENV$("TEMP")&"\STATUS.[SESSION]"
00310 OPEN #(STATUS_HANDLE:=FNGETHANDLE): "NAME="&ENV$("TEMP")&"\STATUS.[SESSION],RECL=512",DISPLAY,INPUT 
00320 LINPUT #STATUS_HANDLE: BUFF$ EOF 390
00330 MAT STATUS$(NSTATUS+=1) !:
      LET STATUS$(NSTATUS)=BUFF$
00340 GOTO 320
00390 CLOSE #STATUS_HANDLE: 
00400 LET GRID_HANDLE$="2,1,LIST "&STR$(WINH-1)&"/"&STR$(WINL-2)
00401 DIM GRID_HEADINGS$(1)*80,GRID_WIDTHS(1),GRID_FORMS$(1)*80
00410 LET GRID_HEADINGS$(1)="Status All"
00420 LET GRID_WIDTHS(1)=WINL
00430 LET GRID_FORMS$(1)="C 132,[T]"
00480 PRINT #IO_WIN,FIELDS GRID_HANDLE$&",headers,[tabs]": (MAT GRID_HEADINGS$,MAT GRID_WIDTHS,MAT GRID_FORMS$)
00490 PRINT #IO_WIN,FIELDS GRID_HANDLE$&",=": MAT STATUS$
00495 LET INP_START=UDIM(STATUS$)
00500 LET CURFLD(1,INP_START)
00510 INPUT #IO_WIN,FIELDS GRID_HANDLE$&",ROWSUB,SELONE": CHOICE
00515 EXECUTE "CON GUI "&ENV_GUI$
00520 PRINT "FKEY ";FKEY;" Detected on Item #";CHOICE !:
      PRINT STATUS$(CHOICE)
00999 END 
02000 DEF FNGETHANDLE
02010 LET NHANDLE=999
02020 DO UNTIL FILE$(NHANDLE)=""
02030 LET NHANDLE-=1
02040 LOOP 
02050 LET FNGETHANDLE=NHANDLE
02090 FNEND